# Maintainer: instantOS <hello@instantos.io>
pkgname=instantmenu
pkgver=5.2.0
# The old C version used a date-based pkgver (e.g. 202105271846), which sorts
# above semver. Epoch 1 lets existing installs upgrade in place.
epoch=1
pkgrel=1
pkgdesc="A dynamic menu for X11 and Wayland"
arch=('x86_64')
url="https://github.com/instantOS/instantMENU"
license=('MIT')
depends=(
    'bash'
    'fontconfig'
    'gcc-libs'
    'glibc'
    'libxcb'
    'libxkbcommon-x11'
)
source=(
    "$pkgname-$pkgver.tar.gz::https://github.com/instantOS/instantMENU/archive/refs/tags/v$pkgver.tar.gz"
    "$pkgname-x86_64-unknown-linux-gnu-v$pkgver.tgz::https://github.com/instantOS/instantMENU/releases/download/v$pkgver/instantmenu-x86_64-unknown-linux-gnu-v$pkgver.tgz"
)
sha256sums=(
    '16e480402febdf07b80b097005a9a6b0c6759538ba9866de0f9be49939388fa0'
    '2c54a7e01e13875c5291ce4fa7e4eb086a6cc67a257694b319191beb91b516ad'
)

package() {
    cd "instantMENU-$pkgver"

    archive="$srcdir/$pkgname-x86_64-unknown-linux-gnu-v$pkgver"

    # Binaries
    install -Dm755 "$archive/instantmenu" "$pkgdir/usr/bin/instantmenu"
    install -Dm755 "$archive/itest" "$pkgdir/usr/bin/itest"

    # Helper scripts
    install -Dm755 "$archive/instantmenu_path" "$pkgdir/usr/bin/instantmenu_path"
    install -Dm755 "$archive/instantmenu_run" "$pkgdir/usr/bin/instantmenu_run"

    # Man page, license, docs
    install -Dm644 "$archive/instantmenu.1" "$pkgdir/usr/share/man/man1/instantmenu.1"
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}
