# Maintainer: instantOS <hello@instantos.io>
pkgname=instantwm
pkgver=0.7.0
pkgrel=2
pkgdesc="A tiling window manager for X11 and Wayland"
arch=('x86_64')
url="https://instantos.io"
license=('MIT')
depends=(
    'libx11'
    'libxcb'
    'libxkbcommon'
    'libxcursor'
    'libxinerama'
    'libxrandr'
    'libxss'
    'libxtst'
    'libxfixes'
    'libxdamage'
    'libxcomposite'
    'libxrender'
    'libxft'
    'libxi'
    'libxres'
    'libxvmc'
    'libxxf86vm'
    'libxt'
    'libxmu'
    'libxpm'
    'libxaw'
    'fontconfig'
    'freetype2'
    'libdrm'
    'mesa'
    'wayland'
    'fuzzel'
    'swaybg'
    'libinput'
    'seatd'
    'libglvnd'
    'libevdev'
    'libwacom'
    'dbus'
    'systemd'
    'xdg-desktop-portal-wlr'
)
source=(
    "$pkgname-$pkgver.tar.gz::https://github.com/instantOS/instantWM/archive/refs/tags/v$pkgver.tar.gz"
    "$pkgname-x86_64-unknown-linux-gnu-v$pkgver.tgz::https://github.com/instantOS/instantWM/releases/download/v$pkgver/instantwm-x86_64-unknown-linux-gnu-v$pkgver.tgz"
)
sha256sums=(
    '9771d20552032d9d9bd1121d0362760b0685ab9d96e4b580497341aa7c0629e0'
    'fa157627ff305868c051c1e16f6cd0f45d6509f008799848a768b25c35e8ac83'
)

package() {
    cd "instantWM-$pkgver"

    # Binaries
    install -Dm755 "$srcdir/instantwm-x86_64-unknown-linux-gnu-v$pkgver/instantwm" "$pkgdir/usr/bin/instantwm"
    install -Dm755 "$srcdir/instantwm-x86_64-unknown-linux-gnu-v$pkgver/instantwmctl" "$pkgdir/usr/bin/instantwmctl"

    # License
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

    # X11 session
    install -Dm755 scripts/startinstantos "$pkgdir/usr/bin/startinstantos"
    install -Dm644 utils/instantwm-x11.desktop "$pkgdir/usr/share/xsessions/instantwm.desktop"

    # Wayland session
    install -Dm644 utils/instantwm-wayland.desktop "$pkgdir/usr/share/wayland-sessions/instantwm-wayland.desktop"

    # Wayland debug session
    install -Dm644 utils/instantwm-wayland-debug.desktop "$pkgdir/usr/share/wayland-sessions/instantwm-debug.desktop"
    install -Dm755 scripts/instantwm-debug.sh "$pkgdir/usr/bin/instantwm-debug"

    # Portal routing for Wayland screen sharing/screenshot support
    install -Dm644 resources/instantwm-portals.conf "$pkgdir/usr/share/xdg-desktop-portal/instantwm-portals.conf"
    install -Dm644 resources/instantwm-session.target "$pkgdir/usr/lib/systemd/user/instantwm-session.target"
}
