Viewing: processing.org

Name

loadJSONArray()

Description

Loads an array of JSON objects from the data folder or a URL, and returns a JSONArray. Per standard JSON syntax, the array must be enclosed in a pair of hard brackets [], and each object within the array must be separated by a comma.

All files loaded and saved by the Processing API use UTF-8encoding.

Examples

Copy

// The following short JSON file called "data.json" is parsed 
// in the code below. It must be in the project's "data" folder.

/*
[
  {
    "id": 0,
    "species": "Capra hircus",
    "name": "Goat"
  },
  {
    "id": 1,
    "species": "Panthera pardus",
    "name": "Leopard"
  },
  {
    "id": 2,
    "species": "Equus zebra",
    "name": "Zebra"
  }
]
*/

JSONArray values;

void setup() {

  values = loadJSONArray("data.json");

  for (int i = 0; i < values.size(); i++) {
    
    JSONObject animal = values.getJSONObject(i); 

    int id = animal.getInt("id");
    String species = animal.getString("species");
    String name = animal.getString("name");

    println(id + ", " + species + ", " + name);
  }
}

// Sketch prints:
// 0, Capra hircus, Goat
// 1, Panthera pardus, Leopard
// 2, Equus zebra, Zebra

Syntax

loadJSONArray(filename)
loadJSONArray(file)

Parameters

filename(String)name of a file in the data folder or aURL

Return

JSONArray

[Creative Commons License]

This work is licensed under a Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International License.

Processing